Upilot – как писать нормальные скрипты и не попасть в ловушку на арене

[Emty]

ребята напешите нормальные скрипты на Upilot ... ну там чтоб на арене не могли сдвинуть ( чтоб на место ставал) или ещё чтото ато я с этой прогой недавно познакомился)) а как писать эти скрипты понятия не имею... помогите ) или сюда или ко мне в асю)) 430-962-698

[Emty]

nanoman
Eng: "User Warned +10% - S.P.A.M. (Stupid Pointless Annoying Message) is not allowed in our forums!"
Rus: "Юзер предупрежден +10% - S.P.A.M. (Тупой Бессмысленний Неприятной Сообшение) неразрешено на нашем форуме!"
Lat: "Lietotājs ticis brīdināts +10% - S.P.A.M. (Stulba Nejēdzīga Nepatīkama Ziņa) nav atļauta mūsu forumā!"
Спасибо за внимание!

[D1ma]

Бедный парень,столько времени прошло а его все забыли  

[Everybody]

Ну да, видимо никто не занимается скриптописанием на уопилоте
Я теперь нужное пробую делать в AutoIT

[jenia]

//Автоатака
right_down 518, 325
Wait 1s

//да на пати или трейд
if 399 173 4344138 4344138
move 399, 173
Double_Left 399, 173
end_if

//Выпивание 2 банок ХП при 50%
if 203, 739 3223601 3223601
move 355, 742
Right 355, 742
Right 355, 742
end_if

//Отмена Дуэли
if 516, 208 5922138
move 588, 419
Double_Left 588, 419
end_if

[jenia]

//как пользоваться: находим подходящее место, выбираем скилл для
//стрельбы (Multishot/Penetration) и запускаем скрипт.
//При необходимости переместится/поднять вещь, приостанавливаем
//работу скрипта (по умолчанию в UoPilot - кнопка Pause.
//Не забываем регулярно летать в город, чинить лук и покупать стрелы.

//Устанавливаем основные переменные, определяющие работу скрипта

//Время для смены направления стрельбы, 1000 = 1 секунда
Set #Click 200

//расстояние до центра до точки, в которую условно дается команда "стрелять"
Set #Dist 100

//Координаты центра экрана (определяются в первую очередь разрешением игры
//1024x768
//Set #XSelf 515
//Set #YSelf 330
//Set #XSelf 370 //Set #YSelf 300
//800x600
Set #XSelf 400
Set #YSelf 230

//Ставим курсор мышки в центр и "зажимаем" правую кнопку мыши.
move #XSelf #Yself
right_down #XSelf #Yself

:StartAE

//Стреляем во все стороны, правая кнопка мыши все время "зажата"
Set #XShoot #Xself + #Dist
Set #YShoot #Yself
move #XShoot, #YShoot
right_down #XShoot, #YShoot
wait #Click

Set #XShoot #Xself + #Dist
Set #YShoot #Yself + #Dist
move #XShoot, #YShoot
right_down #XShoot, #YShoot
wait #Click

Set #XShoot #Xself
Set #YShoot #Yself + #Dist
move #XShoot, #YShoot
right_down #XShoot, #YShoot
wait #Click

Set #XShoot #Xself
Set #YShoot #Yself - #Dist
move #XShoot, #YShoot
right_down #XShoot, #YShoot
wait #Click

Set #XShoot #Xself - #Dist
Set #YShoot #Yself - #Dist
move #XShoot, #YShoot
right_down #XShoot, #YShoot
wait #Click

Set #XShoot #Xself - #Dist
Set #YShoot #Yself
move #XShoot, #YShoot
right_down #XShoot, #YShoot
wait #Click

Set #XShoot #Xself - #Dist
Set #YShoot #Yself + #Dist
move #XShoot, #YShoot
right_down #XShoot, #YShoot
wait #Click

Set #XShoot #Xself + #Dist
Set #YShoot #Yself - #Dist
move #XShoot, #YShoot
right_down #XShoot, #YShoot
wait #Click

Goto StartAE

end_script
=============================================
DW
---------
//Cast
move 518, 325
right_down 518, 325
wait 2s /*wdet 2 sec posle casta*/
//Hp
if 195, 747 526344 526344 /*esli HP menshe etih koordinat 195,747 (526344)-cvet */
move 355, 742 /*podvigaet kursor mishki na koordinati butilok HP*/
Right 355, 742 /*nashimaet na koordinati butilok HP*/
Right 355, 742 -//-
Right 355, 742 -//-
Right 355, 742 -//-
end_i

[jenia]

// Краткое описание действий:
// - каст на Party осуществляется выборочно - только на тех, кто не в дропе и кто есть.
// Т.е. скрипт сам определяет сколько человек в парти и вообще кого надо обкастовывать
// - каст на всю Party щита [раз в 30 секунд] (AS, AutoShield),
// - каст на всю Party усилка [раз в 30 секунд] (AD, AutoDamage),
// - каст на всю Party лечилки [раз в 30 секунд] (AH, AutoHeal),
// - с проверкой [раз в 1-6 секунд] на Party/Trade запросы (AP, AutoParty),
// - с проверкой [раз в 1-6 секунд] жизни и попытки отлечиться бутылками (AL, AutoLife)
// - сохраняется возможность чатиться, но времени на подбор лута практически нет
// (так как обкастовка парти занимает довольно длительное время)
//
//-------------------------------------------------------------
// Настройка скрипта под конкретного чара производится измением
// нижеследующих параметров в этой секции
//-----------
// Определяем, что говорить на Trade/Party
// если 1 - то говорим ДА, иначе (0) - говорим НЕТ
Set #SayYes 1

// кол-во скилов в панельке их выбора (мышкой)
Set #SkillsCount 5

// порядковый номер скила для лечения
// в ряду скилов (когда мышкой выбираем нужный скил)
Set #HealN 1

// порядковый номер скила для щита
// в ряду скилов (когда мышкой выбираем нужный скил)
Set #ShieldlN 2

// порядковый номер скила для усилка
// в ряду скилов (когда мышкой выбираем нужный скил)
Set #DmgN 3

// выставляем максимальное кол-во холостых проходов, т.е. обкаст нашей party
// делаем не постоянно, а только через некоторое время; подбирается экспериментально
// чтобы каст не успевал спадать
Set #MaxTimes 8

//------------------------------
// В данной секции обычно ничего уже менять не надо.
//-----------
// Расчет координат, задание изначальных координат
//-----------
// Определяем координаты кнопки для вызова панели выбора скилов..
// ВНИМАНИЕ: эти координаты принимаются как центр панельки,
// и весь расчет координат происходит на основе этих координат!
//
// Y-координата для начала выбора скилов
Set #Yb 740
// X-координата для начала выбора скилов
Set #Xb 515
// Размер по горизонтали иконки скила (=51)
Set #XSize #Xb / 10
// X-координата для начала отсчета
Set #X0 ( #Xb - ( #SkillsCount * #XSize ) / 2 ) - 1 - ( #XSize / 2 )
// X-координата для выбора скила лечилки
Set #Xh #X0 + #HealN * #XSize
// X-координата для выбора скила защиты
Set #Xs #X0 + #ShieldlN * #XSize
// X-координата для выбора скила повышения урона
Set #Xd #X0 + #DmgN * #XSize

// Y-координата для выбора скила
Set #Ys 625

// координаты для каста "на себя"
Set #XSelf 515
Set #YSelf 290

// координаты слота "Q" (обычно для выпивания бутылочек жизни)
Set #Xq 350
Set #Yq 750

// координаты первого (верхнего) человека в парти
Set #Xcp 988
Set #Ycp 25

//---------------------------
// Вот .. все подсчитали, теперь можно начинать
// Начало скрипта, собственно

Set #i1 #MaxTimes + 1
:StartEE
If #i1 > #MaxTimes
set #i1 0
set #i 1000
Gosub SelectS
Gosub CastParty

Gosub CheckReq
// Gosub CheckLife

set #i 1000
Gosub SelectD
Gosub CastParty

Gosub CheckReq
// Gosub CheckLife

set #i 2000
Gosub SelectH
Gosub CastParty

end_if

set #i1 #i1 + 1

wait 900

Gosub CheckReq
//Gosub CheckLife

Goto StartEE

//---------------------------------------
// Подпрограммы
//----------
// Обкаст всей party
:CastParty
Set #Yp #Ycp - 30
Repeat 5
Set #Yp #Yp + 30
Gosub CastOneP
end_repeat
return
//----------
// Обкаст одного человека на панельке party
:CastOneP
Set #ai1 0
Set #tmpYp #Yp + 8
if #tmpYp > 150
Set #tmpYp #tmpYp + 1
end_if
if 1004, #tmpYp 670514
Set #ai1 1
else
if 1004, #tmpYp 2610
Set #ai1 1
end_if
end_if
if #ai1 = 1
Move #Xcp, #Yp
Right_down #Xcp, #Yp
Wait #i
Right_up #Xcp, #Yp
end_if
return
//----------
//Начало Выбора
:BeginSelect
Move #Xb, #Yb
Left_down #Xb, #Yb
// Wait 1
Left_Up #Xb, #Yb
Wait 750
return
//----------
// Выбор лечилок
:SelectHeal
Move #Xh, #Ys
Left_down #Xh, #Ys
// Wait 1
Left_Up #Xh, #Ys
return
//----------
// Выбор щита
:SelectShield
Move #Xs, #Ys
Left_down #Xs, #Ys
// Wait 1
Left_Up #Xs, #Ys
return
//----------
// Выбор урона
:SelectDmg
Move #Xd, #Ys
Left_down #Xd, #Ys
// Wait 1
Left_Up #Xd, #Ys
return
//----------
// Выбор с Heal
:SelectH
Gosub BeginSelect
Gosub SelectHeal
return
//----------
// Выбор Shield
:SelectS
Gosub BeginSelect
Gosub SelectShield
return
//----------
// Выбор Dmg
:SelectD
Gosub BeginSelect
Gosub SelectDmg
return
//----------
// Проверка на Party или Trade
:CheckReq
// для 16 bits
// if 399, 173 4868434
if 399, 173 4344138
if #SayYes = 1
move 400, 172
Left_Down 400, 172
// Wait 1
Left_Up 400, 172
else
move 550, 172
Left_Down 550, 172
// Wait 1
Left_Up 550, 172
end_if
// вертаем курсор в центр
Move #XSelf, #Yself
end_if
return
//----------
//проверка на жисть (если менее примерно 70%, то пьем 4 баночки из слота Q)
:CheckLife
// для 16 bits
// if_not 200, 720 200
if_not 200, 720 198
Repeat 4
Move #Xq, #Yq
Right_Down #Xq, #Yq
// Wait 1
Right_Up #Xq, #Yq
Wait 250
End_Repeat
// вертаем курсор в центр
Move #XSelf, #Yself
end_if
return

[ubik]

банально, эти скрипты легко сбить так как используют разрешение экрана если свернуть окно МУ эти все скрипты загнутся))) ну может не все но 99% не будут работать и будут глюки